【结贴】[请求]代码什么意思**

Crazy_wen2006

constructor TQXJLXX.Create(AContext: TContext);
begin
  inherited Create(AContext);
  FData := TSheetDataSetContainer.Create();
  FData.FDataSets := [DataSetGDJCXX,DataSetGDFJWDB,DataSetKSGSJB,
                                          DataSetGDAQCSB,DataSetGDFZRGHB,DataSetGZCYGHB,DataSetYJMX];
  
end;

请问红色部分是构造一个数据集吗？是将几个数据集合起来还是怎么？谢谢

zfang

楼主，请看以下TSheetDataSetContainer这个对象的具体信息
看着像是一个数据集的容器。

Crazy_wen2006

TSheetDataSetContainer = class
  private
    function GetConnection: TConnection;
    function GetMaster: TSQLDataSet;
    function GetDataSetCount: Integer;
    function GetDataSet(Index: Integer): TSQLDataSet;
  public
    FDataSets: array of TSQLDataSet;
    procedure UpdateRecords;
    function ConfirmUpdates: Boolean;
    function UpdatesPending: Boolean;
    procedure ApplyUpdates;
    procedure CancelUpdates;
    procedure DisableControls;
    procedure EnableControls;
    property Connection: TConnection read GetConnection;
    property Master: TSQLDataSet read GetMaster;

    property DataSets[Index: Integer]: TSQLDataSet read GetDataSet;
    property DataSetCount: Integer read GetDataSetCount;
  end;

function TSheetDataSetContainer.GetConnection: TConnection;
begin
  Result := Master.Connection;
end;

function TSheetDataSetContainer.GetMaster: TSQLDataSet;
begin
  Result := DataSets[0];
end;

function TSheetDataSetContainer.GetDataSetCount: Integer;
begin
  if FDataSets = nil then
    Result := 0
  else
    Result := Length(FDataSets);
end;

function TSheetDataSetContainer.GetDataSet(Index: Integer): TSQLDataSet;
begin
  Result := FDataSets[Index];
end;

procedure TSheetDataSetContainer.UpdateRecords;
var
  I: Integer;
begin
  for I := 0 to DataSetCount - 1 do
  begin
    if (DataSets[I] <> nil) and
      (DataSets[I].State in [TDataSetState.dsEdit, TDataSetState.dsInsert]) and
      DataSets[I].Modified then
      begin
        DataSets[I].UpdateRecord;
        DataSets[I].Post;
      end;
  end;
end;

function TSheetDataSetContainer.ConfirmUpdates: Boolean;
begin
  Result := True;

  if UpdatesPending then
    case JSDialogs.QuestionBox('数据已经被修改，是否保存？', Forms.Application.Title, 1) of
      Borland.Delphi.Windows.IDYES:
        ApplyUpdates;
      Borland.Delphi.Windows.IDNO:
        CancelUpdates;
    else
      Result := False;
    end;
end;

function TSheetDataSetContainer.UpdatesPending: boolean;
var
  I: Integer;
begin
  for I := 0 to DataSetCount - 1 do
    if (DataSets[I] <> nil) and
      DataSets[I].UpdatesPending and
      DataSets[I].UpdateOptions.Enabled then
    begin
      Result := not Master.IsEmpty;
      Exit;
    end;

  Result := False;
end;

procedure TSheetDataSetContainer.ApplyUpdates;
var
  I: Integer;
begin
  for I := 0 to DataSetCount - 1 do
  begin
    try
    if (DataSets[I] <> nil) and
      DataSets[I].UpdatesPending and
      DataSets[I].UpdateOptions.Enabled {and
      not DataSets[I].Relation.Active }then
      DataSets[I].ApplyUpdates(False);
    except
      continue;
    end;
  end;
end;

procedure TSheetDataSetContainer.CancelUpdates;
var
  I: Integer;
begin
  for I := 0 to DataSetCount - 1 do
  begin
    if DataSets[I] = nil then
      Continue;

    if DataSets[I].State in [TDataSetState.dsInsert, TDataSetState.dsEdit] then
      DataSets[I].Cancel;
    if DataSets[I].UpdatesPending then
      DataSets[I].CancelUpdates;
  end;
end;

procedure TSheetDataSetContainer.DisableControls;
var
  I: Integer;
begin
  for I := 0 to DataSetCount - 1 do
    if DataSets[I] <> nil then
      DataSets[I].DisableControls;
end;

procedure TSheetDataSetContainer.EnableControls;
var
  I: Integer;
begin
  for I := 0 to DataSetCount - 1 do
    if DataSets[I] <> nil then
      DataSets[I].EnableControls;
end;

zfang

看这个类的定义
FDataSets: array of TSQLDataSet;

FDataSets是一个标准数据集的数组
那么1楼的代码就是给这个数组赋值。

Crazy_wen2006

谢谢斑竹，结贴。。